File PKGBUILD of Package libva-bootstrap

# Maintainer: Yukari Chiba <[email protected]>

pkgname=libva
pkgver=2.23.0
pkgrel=1
pkgdesc='Video Acceleration (VA) API for Linux'
arch=(x86_64 aarch64 riscv64 loongarch64)
url=https://01.org/linuxmedia/vaapi
license=(MIT)
depends=(
  libdrm
  wayland
)
makedepends=(
  git
  libglvnd
  linux-headers
  meson
)
optdepends=(
  'intel-media-driver: backend for Intel GPUs (>= Broadwell)'
  'libva-intel-driver: backend for Intel GPUs (<= Haswell)'
  'libva-mesa-driver: backend for AMD and NVIDIA GPUs'
)
provides=(
  libva-drm.so
  libva-wayland.so
  libva.so
)
backup=(etc/libva.conf)
source=(git+https://github.com/intel/libva.git#tag=$pkgver)
sha256sums=('1819b31a1ae54957db182ed1d1ea119965f02d262b70e9dc81ca1ee133b6f9d4')

build() {
  CFLAGS+=" -DENABLE_VA_MESSAGING" # Option missing
  ewe-meson libva build -D with_x11=no -D with_glx=no -D with_win32=no
  meson compile -C build
}

package() {
  meson install -C build --destdir "${pkgdir}"
  install -Dm 644 libva/COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
  install -Dm 644 /dev/stdin "${pkgdir}"/etc/libva.conf <<END
LIBVA_MESSAGING_LEVEL=1
END
}