File PKGBUILD of Package xrdp

# Maintainer: Yukari Chiba <[email protected]>

pkgname=xrdp
pkgver=0.10.6
pkgrel=1
pkgdesc="An open source remote desktop protocol (RDP) server"
url="https://github.com/neutrinolabs/xrdp"
arch=(x86_64 aarch64 riscv64 loongarch64)
license=('Apache-2.0')
makedepends=('nasm' 'cmocka')
depends=('ffmpeg' 'fuse3' 'x264' 'pam' 'lame')
checkdepends=('check')
optdepends=('tigervnc' 'tightvnc' 'realvnc-vnc-server')
backup=('etc/xrdp/sesman.ini'
	'etc/xrdp/xrdp.ini'
	'etc/xrdp/cert.pem'
	'etc/xrdp/key.pem'
	'etc/xrdp/startwm.sh'
	'etc/xrdp/reconnectwm.sh'
	'etc/default/xrdp')
install="${pkgname}.install"
# neatvnc.patch::https://github.com/neutrinolabs/xrdp/commit/527d21b0a161abd8a65518b80c707c52117fc04d.patch
source=(
  "https://github.com/neutrinolabs/xrdp/releases/download/v${pkgver//_/-}/xrdp-${pkgver//_/-}.tar.gz"
  no-x11.patch
)
sha256sums=('SKIP' 'SKIP')

prepare() {
  _patch_ "${pkgname}-${pkgver//_/-}"
  cd "${pkgname}-${pkgver//_/-}"
  ./bootstrap
}

build() {
  cd "${pkgname}-${pkgver//_/-}"
  ./configure --prefix=/usr \
              --sysconfdir=/etc \
              --libexecdir=/usr/lib \
              --localstatedir=/var \
              --sbindir=/usr/bin \
              --with-systemdsystemunitdir=no \
              --enable-jpeg \
              --enable-tjpeg \
              --enable-fuse \
	      --enable-fdkaac=no \
	      --enable-opus \
	      --enable-rfxcodec \
	      --enable-mp3lame \
	      --enable-pixman \
	      --enable-painter \
	      --enable-vsock \
	      --enable-ipv6 \
	      --enable-pam-config=arch \
	      --enable-rdpsndaudin \
	      --with-imlib2=no \
	      --enable-x264
  # Fight unused direct deps
  sed -i -e "s| -shared | $LDFLAGS\0 |g" -e "s|    if test \"\$export_dynamic\" = yes && test -n \"\$export_dynamic_flag_spec\"; then|      func_append compile_command \" $LDFLAGS\"\n      func_append finalize_command \" $LDFLAGS\"\n\0|" libtool
  export MAKEFLAGS="CC=cc CXX=c++ -j$JOBS"
  make
}

check () {
  cd "${pkgname}-${pkgver//_/-}"
  export MAKEFLAGS="CC=cc CXX=c++ -j$JOBS"
  # FAIL: test_xrdp 15 - test_xrdp_region.c:test_xrdp_region:execute_suite
  make check || :
}

package() {
  cd "${pkgname}-${pkgver//_/-}"
  sed -i 's^param=Xorg^param=/usr/lib/Xorg^g' sesman/sesman.ini
  export MAKEFLAGS="CC=cc CXX=c++ -j$JOBS"
  make DESTDIR="$pkgdir" install
  rm -f "$pkgdir"/etc/xrdp/rsakeys.ini
  install -Dm644 COPYING "$pkgdir"/usr/share/licenses/$pkgname/COPYING
  install -Dm644 instfiles/default/xrdp "$pkgdir"/etc/default/xrdp
}