File PKGBUILD of Package kwin

# Maintainer: Yukari Chiba <[email protected]>

pkgname=kwin
pkgver=6.5.2
_dirver=$(echo $pkgver | cut -d. -f1-3)
pkgrel=1
pkgdesc='An easy to use, but flexible, composited Window Manager'
arch=(x86_64 aarch64 riscv64)
url='https://kde.org/plasma-desktop/'
license=(LGPL-2.0-or-later)
depends=(breeze
         plasma-activities
         kauth
         kcmutils
         kcolorscheme
         kconfig
         kconfigwidgets
         kcoreaddons
         kcrash
         kdbusaddons
         kdeclarative
         kdecoration
         kglobalaccel
         kguiaddons
         ki18n
         kidletime
         kirigami
         kitemmodels
         knewstuff
         knotifications
         kpackage
         kquickcharts
         kservice
         ksvg
         kwayland
         kwidgetsaddons
         kwindowsystem
         kxmlgui
         lcms2
         libdisplay-info
         libdrm
         libei
         libepoxy
         libinput
         libpipewire
         libqaccessibilityclient-qt6
         libxcvt
         libxkbcommon
         mesa
         pipewire-session-manager
         libplasma
         qt6-5compat
         qt6-base
         qt6-declarative
         qt6-multimedia
         qt6-sensors
         qt6-tools
         qt6-wayland
         seatd
         wayland)
makedepends=(extra-cmake-modules
             krunner
             plasma-wayland-protocols
             python
             wayland-protocols
             linux-headers)
optdepends=('maliit-keyboard: virtual keyboard for kwin-wayland')
groups=(plasma)
source=(
  https://download.kde.org/stable/plasma/$_dirver/$pkgname-$pkgver.tar.xz
  no-x11.patch
  session-seatd.patch
)
options=(!strip)
sha256sums=('SKIP' 'SKIP' 'SKIP')

prepare() {
  _patch_ "$pkgname-$pkgver"
}

build() {
  cmake -B build  -S $pkgname-$pkgver \
    -DCMAKE_INSTALL_LIBEXECDIR=lib \
    -DBUILD_TESTING=OFF \
    -DKWIN_BUILD_X11=OFF \
    -DKWIN_BUILD_X11_BACKEND=OFF \
    -DKWIN_BUILD_GLOBALSHORTCUTS=OFF \
    -DKWIN_BUILD_SCREENLOCKER=OFF \
    -DCMAKE_BUILD_TYPE=Debug
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
  
  # plasma-kwin_wayland.service
  rm -r $pkgdir/usr/lib/systemd
}