File PKGBUILD of Package enlightenment

# Maintainer: Yukari Chiba <[email protected]>

pkgname=enlightenment
pkgver=0.28.0
pkgrel=1
pkgdesc="Enlightenment window manager"
arch=(x86_64 aarch64 riscv64 loongarch64)
url="http://www.enlightenment.org"
license=('BSD')
depends=('alsa-lib' 'efl' 'hicolor-icon-theme' 'libexif' 'librsvg' 'libpulse'
         'libxkbcommon' 'pam' 'util-linux-libs'
         'wayland')
optdepends=('acpid: power events on laptop lid close'
            'bluez: Bluetooth control module'
            'connman: network connection manager module'
            'fprintd: fingerprint password settings'
            'geoclue: geolocation module'
            'packagekit: package manager integration module')
makedepends=('meson' 'ninja' 'wayland-protocols' 'git')
backup=('etc/enlightenment/sysactions.conf'
        'etc/enlightenment/system.conf'
        'etc/xdg/menus/e-applications.menu')
source=("https://download.enlightenment.org/rel/apps/${pkgname}/$pkgname-$pkgver.tar.xz" no-x11.patch)
sha256sums=('SKIP' 'SKIP')

prepare() {
  _patch_ ${pkgname}-${pkgver}
}

build() {
  CFLAGS+=' -fvisibility=hidden'

  ewe-meson ${pkgname}-${pkgver} build \
    -Dwl=true \
    -Dwl-x11=false \
    -Dxwayland=false \
    -Dsystemd=false \
    -Dconvertible=false
  meson compile -C build
}


package() {
  depends+=('ttf-font')
  meson install -C build --destdir "$pkgdir"
  
  # install LICENSE
  install -Dm644 ${srcdir}/${pkgname}-${pkgver}/COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}